home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS05.ADF / asm / mydev.asm < prev    next >
Assembly Source File  |  1986-01-15  |  25KB  |  943 lines
  1.  
  2. * mydev.asm AmigaLink 1/30/86
  3. *************************************************************************
  4. *                                            *
  5. *    Copyright (C) 1985, Commodore Amiga Inc.  All rights reserved.   *
  6. *                                            *
  7. ************************************************************************/
  8.  
  9.  
  10. *************************************************************************
  11. *
  12. * mydev.asm -- skeleton device code
  13. *
  14. * Source Control
  15. * ------ -------
  16. * 
  17. * $Header: amain.asm,v 31.3 85/10/18 19:04:04 neil Exp $
  18. *
  19. * $Locker: neil $
  20. *
  21. * $Log:   amain.asm,v $
  22. *
  23. ************************************************************************/
  24.      SECTION   section
  25.  
  26.      NOLIST
  27.      include "exec/types.i"
  28.      include "exec/nodes.i"
  29.      include "exec/lists.i"
  30.      include "exec/libraries.i"
  31.      include "exec/devices.i"
  32.      include "exec/io.i"
  33.      include "exec/alerts.i"
  34.      include "exec/initializers.i"
  35.      include "exec/memory.i"
  36.      include "exec/resident.i"
  37.      include "exec/ables.i"
  38.      include "exec/errors.i"
  39.      include "libraries/dos.i"
  40.      include "libraries/dosextens.i"
  41.  
  42.      include "asmsupp.i"
  43.      include "messages.i"
  44.  
  45.      include "mydev.i"
  46.  
  47.      LIST
  48.  
  49. INFO_LEVEL equ 40
  50.  
  51.      ;------ These don't have to be external, but it helps some
  52.      ;------ debuggers to have them globally visible
  53.      XDEF Init
  54.      XDEF Open
  55.      XDEF Close
  56.      XDEF Expunge
  57.      XDEF Null
  58.      XDEF myName
  59.      XDEF BeginIO
  60.      XDEF AbortIO
  61.  
  62.      XREF _AbsExecBase
  63.  
  64.      XLIB OpenLibrary
  65.      XLIB CloseLibrary
  66.      XLIB Alert
  67.      XLIB FreeMem
  68.      XLIB Remove
  69.      XLIB FindTask
  70.      XLIB AllocMem
  71.      XLIB CreateProc
  72.      XLIB PutMsg
  73.      XLIB RemTask
  74.      XLIB ReplyMsg
  75.      XLIB Signal
  76.      XLIB GetMsg
  77.      XLIB Wait
  78.      XLIB WaitPort
  79.      XLIB AllocSignal
  80.      XLIB SetTaskPri
  81.  
  82.      INT_ABLES
  83.  
  84.  
  85.      ; The first executable location.  This should return an error
  86.      ; in case someone tried to run you as a program (instead of
  87.      ; loading you as a library).
  88. FirstAddress:
  89.      CLEAR     d0
  90.      rts
  91.  
  92. ;-----------------------------------------------------------------------
  93. ; A romtag structure.  Both "exec" and "ramlib" look for
  94. ; this structure to discover magic constants about you
  95. ; (such as where to start running you from...).
  96. ;-----------------------------------------------------------------------
  97.  
  98.      ; Most people will not need a priority and should leave it at zero.
  99.      ; the RT_PRI field is used for configuring the roms.  Use "mods" from
  100.      ; wack to look at the other romtags in the system
  101. MYPRI     EQU  0
  102.  
  103. initDDescrip:
  104.                          ;STRUCTURE RT,0
  105.        DC.W    RTC_MATCHWORD       ; UWORD RT_MATCHWORD
  106.        DC.L    initDDescrip        ; APTR  RT_MATCHTAG
  107.        DC.L    EndCode        ; APTR  RT_ENDSKIP
  108.        DC.B    RTF_AUTOINIT        ; UBYTE RT_FLAGS
  109.        DC.B    VERSION        ; UBYTE RT_VERSION
  110.        DC.B    NT_DEVICE      ; UBYTE RT_TYPE
  111.        DC.B    MYPRI               ; BYTE  RT_PRI
  112.        DC.L    myName         ; APTR  RT_NAME
  113.        DC.L    idString       ; APTR  RT_IDSTRING
  114.        DC.L    Init           ; APTR  RT_INIT
  115.                          ; LABEL RT_SIZE
  116.  
  117.  
  118.      ; this is the name that the device will have
  119. subSysName:
  120. myName:        MYDEVNAME
  121.  
  122.      ; a major version number.
  123. VERSION:  EQU  1
  124.  
  125.      ; A particular revision.  This should uniquely identify the bits in the
  126.      ; device.  I use a script that advances the revision number each time
  127.      ; I recompile.  That way there is never a question of which device
  128.      ; that really is.
  129. REVISION: EQU  17
  130.  
  131.      ; this is an identifier tag to help in supporting the device
  132.      ; format is 'name version.revision (dd MON yyyy)',<cr>,<lf>,<null>
  133. idString: dc.b 'mydev 1.0 (31 Oct 1985)',13,10,0
  134.  
  135. dosName:  DOSNAME
  136.  
  137.      ; force word allignment
  138.      ds.w 0
  139.  
  140.  
  141.      ; The romtag specified that we were "RTF_AUTOINIT".  This means
  142.      ; that the RT_INIT structure member points to one of these
  143.      ; tables below.  If the AUTOINIT bit was not set then RT_INIT
  144.      ; would point to a routine to run.
  145.  
  146. Init:
  147.      DC.L MyDev_Sizeof        ; data space size
  148.      DC.L funcTable      ; pointer to function initializers
  149.      DC.L dataTable      ; pointer to data initializers
  150.      DC.L initRoutine         ; routine to run
  151.  
  152.  
  153. funcTable:
  154.  
  155.      ;------ standard system routines
  156.      dc.l Open
  157.      dc.l Close
  158.      dc.l Expunge
  159.      dc.l Null
  160.  
  161.      ;------ my device definitions
  162.      dc.l BeginIO
  163.      dc.l AbortIO
  164.  
  165.      ;------ function table end marker
  166.      dc.l -1
  167.  
  168.  
  169.      ; The data table initializes static data structures.
  170.      ; The format is specified in exec/InitStruct routine's
  171.      ; manual pages.  The INITBYTE/INITWORD/INITLONG routines
  172.      ; are in the file "exec/initializers.i".  The first argument
  173.      ; is the offset from the device base for this byte/word/long.
  174.      ; The second argument is the value to put in that cell.
  175.      ; The table is null terminated
  176. dataTable:
  177.      INITBYTE  LH_TYPE,NT_DEVICE
  178.      INITLONG  LN_NAME,myName
  179.      INITBYTE  LIB_FLAGS,LIBF_SUMUSED!LIBF_CHANGED
  180.      INITWORD  LIB_VERSION,VERSION
  181.      INITWORD  LIB_REVISION,REVISION
  182.      INITLONG  LIB_IDSTRING,idString
  183.      DC.L 0
  184.  
  185.  
  186.      ; This routine gets called after the device has been allocated.
  187.      ; The device pointer is in D0.  The segment list is in a0.
  188.      ; If it returns non-zero then the device will be linked into
  189.      ; the device list.
  190. initRoutine:
  191.  
  192.      ;------ get the device pointer into a convenient A register
  193.      move.l    a5,-(sp)
  194.      move.l    d0,a5
  195.  
  196.      ;------ save a pointer to exec
  197.      move.l    a6,md_SysLib(a5)
  198.  
  199.      ;------ save a pointer to our loaded code
  200.      move.l    a0,md_SegList(a5)
  201.  
  202.      ;------ open the dos library
  203.      lea  dosName(pc),a1
  204.      CLEAR     d0
  205.      CALLSYS   OpenLibrary
  206.  
  207.      move.l    d0,md_DosLib(a5)
  208.      bne.s     init_DosOK
  209.  
  210.      ;------ can't open the dos!  what gives
  211.      ALERT     AG_OpenLib!AO_DOSLib
  212.  
  213. init_DosOK:
  214.      ;------ now build the static data that we need
  215.  
  216.      ;
  217.      ; put your initialization here...
  218.      ;
  219.  
  220.      move.l    a5,d0
  221.      move.l    (sp)+,a5
  222.      rts
  223.  
  224. ;----------------------------------------------------------------------
  225. ;
  226. ; here begins the system interface commands.  When the user calls
  227. ; OpenLibrary/CloseLibrary/RemoveLibrary, this eventually gets translated
  228. ; into a call to the following routines (Open/Close/Expunge).  Exec
  229. ; has already put our device pointer in a6 for us.  Exec has turned
  230. ; off task switching while in these routines (via Forbid/Permit), so
  231. ; we should not take too long in them.
  232. ;
  233. ;----------------------------------------------------------------------
  234.  
  235.  
  236.      ; Open sets the IO_ERROR field on an error.  If it was successfull,
  237.      ; we should set up the IO_UNIT field.
  238.  
  239. Open:          ; ( device:a6, iob:a1, unitnum:d0, flags:d1 )
  240.      movem.l   d2/a2/a3/a4,-(sp)
  241.  
  242.      move.l    a1,a2          ; save the iob
  243.  
  244.      ;------ see if the unit number is in range
  245.      moveq     #MD_NUMUNITS,d2
  246.      cmp.l     d2,d0
  247.      bcc.s     Open_Error     ; unit number out of range
  248.  
  249.      ;------ see if the unit is already initialized
  250.      move.l    d0,d2          ; save unit number
  251.      lsl.l     #2,d0
  252.      lea.l     md_Units(a6,d0.l),a4
  253.      move.l    (a4),d0
  254.      bne.s     Open_UnitOK
  255.  
  256.      ;------ try and conjure up a unit
  257.      bsr  InitUnit
  258.  
  259.      ;------ see if it initialized OK
  260.      move.l    (a4),d0
  261.      beq.s     Open_Error
  262.  
  263. Open_UnitOK:
  264.      move.l    d0,a3          ; unit pointer in a3
  265.  
  266.      move.l    d0,IO_UNIT(a2)
  267.  
  268.      ;------ mark us as having another opener
  269.      addq.w    #1,LIB_OPENCNT(a6)
  270.      addq.w    #1,UNIT_OPENCNT(a3)
  271.  
  272.      ;------ prevent delayed expunges
  273.      bclr #LIBB_DELEXP,md_Flags(a6)
  274.  
  275. Open_End:
  276.  
  277.      movem.l   (sp)+,d2/a2/a3/a4
  278.      rts
  279.  
  280. Open_Error:
  281.      move.b    #IOERR_OPENFAIL,IO_ERROR(a2)
  282.      bra.s     Open_End
  283.  
  284.      ; There are two different things that might be returned from
  285.      ; the Close routine.  If the device is no longer open and
  286.      ; there is a delayed expunge then Close should return the
  287.      ; segment list (as given to Init).  Otherwise close should
  288.      ; return NULL.
  289.  
  290. Close:         ; ( device:a6, iob:a1 )
  291.      movem.l   a2/a3,-(sp)
  292.  
  293.      move.l    a1,a2
  294.  
  295.      move.l    IO_UNIT(a2),a3
  296.  
  297.      ;------ make sure the iob is not used again
  298.      moveq.l   #-1,d0
  299.      move.l    d0,IO_UNIT(a2)
  300.      move.l    d0,IO_DEVICE(a2)
  301.  
  302.      ;------ see if the unit is still in use
  303.      subq.w    #1,UNIT_OPENCNT(a3)
  304.      bne.s     Close_Device
  305.  
  306.      bsr  ExpungeUnit
  307.  
  308. Close_Device:
  309.      ;------ mark us as having one fewer openers
  310.      subq.w    #1,LIB_OPENCNT(a6)
  311.  
  312.      ;------ see if there is anyone left with us open
  313.      bne.s     Close_End
  314.  
  315.      ;------ see if we have a delayed expunge pending
  316.      btst #LIBB_DELEXP,md_Flags(a6)
  317.      beq.s     Close_End
  318.  
  319.      ;------ do the expunge
  320.      bsr  Expunge
  321.  
  322. Close_End:
  323.      movem.l   (sp)+,a2/a3
  324.      rts
  325.  
  326.  
  327.      ; There are two different things that might be returned from
  328.      ; the Expunge routine.  If the device is no longer open
  329.      ; then Expunge should return the segment list (as given to
  330.      ; Init).  Otherwise Expunge should set the delayed expunge
  331.      ; flag and return NULL.
  332.      ;
  333.      ; One other important note: because Expunge is called from
  334.      ; the memory allocator, it may NEVER Wait() or otherwise
  335.      ; take long time to complete.
  336.  
  337. Expunge:  ; ( device: a6 )
  338.  
  339.      movem.l   d2/a5/a6,-(sp)
  340.      move.l    a6,a5
  341.      move.l    md_SysLib(a5),a6
  342.      
  343.      ;------ see if anyone has us open
  344.      tst.w     LIB_OPENCNT(a5)
  345.      beq  1$
  346.  
  347.      ;------ it is still open.  set the delayed expunge flag
  348.      bset #LIBB_DELEXP,md_Flags(a5)
  349.      CLEAR     d0
  350.      bra.s     Expunge_End
  351.  
  352. 1$:
  353.      ;------ go ahead and get rid of us.  Store our seglist in d2
  354.      move.l    md_SegList(a5),d2
  355.  
  356.      ;------ unlink from device list
  357.      move.l    a5,a0
  358.      CALLSYS   Remove
  359.      
  360.      ;
  361.      ; device specific closings here...
  362.      ;
  363.  
  364.      ;------ close the dos library
  365.      move.l    md_DosLib(a5),a1
  366.      CALLSYS   CloseLibrary
  367.  
  368.      ;------ free our memory
  369.      move.l    a5,a1
  370.      move.l    LIB_NEGSIZE(a5),d0
  371.  
  372.      sub.l     d0,a1
  373.      add.l     LIB_POSSIZE(a5),d0
  374.  
  375.      CALLSYS   FreeMem
  376.  
  377.      ;------ set up our return value
  378.      move.l    d2,d0
  379.  
  380. Expunge_End:
  381.      movem.l   (sp)+,d2/a5/a6
  382.      rts
  383.  
  384.  
  385. Null:
  386.      CLEAR     d0
  387.      rts
  388.  
  389.  
  390. InitUnit: ; ( d2:unit number, a3:scratch, a6:devptr )
  391.      movem.l   d2/d3/d4,-(sp)
  392.  
  393.      ;------ allocate unit memory
  394.      move.l    #MyDevUnit_Sizeof,d0
  395.      move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  396.      LINKSYS   AllocMem,md_SysLib(a6)
  397.  
  398.      tst.l     d0
  399.      beq  InitUnit_End
  400.  
  401.      move.l    d0,a3
  402.      move.b    d2,mdu_UnitNum(a3)  ; initialize unit number
  403.  
  404.      ;------ start up the unit process.  We do a trick here --
  405.      ;------ we set his message port to PA_IGNORE until the
  406.      ;------ new process has a change to set it up.
  407.      ;------ We cannot go to sleep here: it would be very nasty
  408.      ;------ if someone else tried to open the unit
  409.      ;------ (exec's OpenDevice has done a Forbid() for us --
  410.      ;------ we depend on this to become single threaded).
  411.      move.l    #MYPROCSTACKSIZE,d4 ; stack size
  412.      move.l    #myproc_seglist,d3  ; segment list
  413.      lsr.l     #2,d3               ; change to bcpl pointer
  414.      moveq     #MYPROCPRI,d2       ; pick out its priority
  415.      move.l    #myName,d1          ; name is the device's
  416.      LINKSYS   CreateProc,md_DosLib(a6)
  417.  
  418.      tst.l     d0
  419.      beq  InitUnit_FreeUnit
  420.  
  421.           IFGE INFO_LEVEL-1
  422.           move.l    d0,-(sp)
  423.           move.l    a3,-(sp)
  424.           PUTMSG    1,<'%s/InitUnit: unit 0x%lx process 0x%lx'>
  425.           addq.l    #8,sp
  426.           ENDC
  427.  
  428.      ;------ set up the unit structures for the new process
  429.      move.l    d0,mdu_Process(a3)
  430.      move.l    d0,a0
  431.      lea  -pr_MsgPort(a0),a0
  432.      move.l    a0,MP_SIGTASK(a3)
  433.      move.b    #PA_IGNORE,MP_FLAGS(a3)
  434.  
  435.      ;------ send a startup message to the new process
  436.      lea  mdu_Msg(a3),a1
  437.      move.l    a3,mdm_Unit(a1)
  438.      move.l    a6,mdm_Device(a1)
  439.      move.l    d0,a0               ; message port is new process port
  440.      LINKSYS   PutMsg,md_SysLib(a6)
  441.  
  442.      ;------ mark us as ready to go
  443.      move.l    d2,d0               ; unit number
  444.      lsl.l     #2,d0
  445.      move.l    a3,md_Units(a6,d0.l)     ; set unit table
  446.  
  447.  
  448. InitUnit_End:
  449.      movem.l   (sp)+,d2/d3/d4
  450.      rts
  451.  
  452.      ;------ got an error.  free the unit structure that we allocated.
  453. InitUnit_FreeUnit:
  454.      bsr  FreeUnit
  455.      bra.s     InitUnit_End
  456.  
  457. FreeUnit: ; ( a3:unitptr, a6:deviceptr )
  458.      move.l    a3,a1
  459.      move.l    #MyDevUnit_Sizeof,d0
  460.      LINKSYS   FreeMem,md_SysLib(a6)
  461.      rts
  462.  
  463.  
  464. ExpungeUnit:   ; ( a3:unitptr, a6:deviceptr )
  465.      move.l    d2,-(sp)
  466.  
  467.      ;------ get rid of the unit's task.  We know this is safe
  468.      ;------ because the unit has an open count of zero, so it
  469.      ;------ is 'guaranteed' not in use.
  470.      move.l    mdu_Process(a3),a1
  471.      lea  -(pr_MsgPort)(a1),a1
  472.      LINKSYS   RemTask,md_SysLib(a6)
  473.  
  474.      ;------ save the unit number
  475.      CLEAR     d2
  476.      move.b    mdu_UnitNum(a3),d2
  477.  
  478.      ;------ free the unit structure.
  479.      bsr  FreeUnit
  480.  
  481.      ;------ clear out the unit vector in the device
  482.      lsl.l     #2,d2
  483.      clr.l     md_Units(a6,d2.l)
  484.  
  485.      move.l    (sp)+,d2
  486.  
  487.      rts
  488.  
  489. ;----------------------------------------------------------------------
  490. ;
  491. ; here begins the device specific functions
  492. ;
  493. ;----------------------------------------------------------------------
  494.  
  495. ; cmdtable is used to look up the address of a routine that will
  496. ; implement the device command.
  497. cmdtable:
  498.      DC.L Invalid        ; $00000001
  499.      DC.L MyReset        ; $00000002
  500.      DC.L Read      ; $00000004
  501.      DC.L Write          ; $00000008
  502.      DC.L Update         ; $00000010
  503.      DC.L Clear          ; $00000020
  504.      DC.L MyStop         ; $00000040
  505.      DC.L Start          ; $00000080
  506.      DC.L Flush          ; $00000100
  507.      DC.L Foo       ; $00000200
  508.      DC.L Bar       ; $00000400
  509. cmdtable_end:
  510.  
  511. ; this define is used to tell which commands should not be queued
  512. ; command zero is bit zero.
  513. ; The immediate commands are Invalid, Reset, Stop, Start, Flush
  514. IMMEDIATES     EQU  $000001c3
  515.  
  516. ;
  517. ; BeginIO starts all incoming io.  The IO is either queued up for the
  518. ; unit task or processed immediately.
  519. ;
  520.  
  521. BeginIO:  ; ( iob: a1, device:a6 )
  522.      move.l    a3,-(sp)
  523.  
  524.      ;------ bookkeeping
  525.      move.l    IO_UNIT(a1),a3
  526.  
  527.      ;------ see if the io command is within range
  528.      move.w    IO_COMMAND(a1),d0
  529.      cmp.w     #MYDEV_END,d0
  530.      bcc.s     BeginIO_NoCmd
  531.  
  532.      DISABLE   a0
  533.  
  534.      ;------ process all immediate commands no matter what
  535.      move.w    #IMMEDIATES,d1
  536.      btst d0,d1
  537.      bne.s     BeginIO_Immediate
  538.  
  539.      ;------ see if the unit is STOPPED.  If so, queue the msg.
  540.      btst #MDUB_STOPPED,UNIT_FLAGS(a3)
  541.      bne.s     BeginIO_QueueMsg
  542.  
  543.      ;------ this is not an immediate command.  see if the device is
  544.      ;------ busy.
  545.      bset #UNITB_ACTIVE,UNIT_FLAGS(a3)
  546.      beq.s     BeginIO_Immediate
  547.  
  548.      ;------ we need to queue the device.  mark us as needing
  549.      ;------ task attention.  Clear the quick flag
  550. BeginIO_QueueMsg:
  551.      BSET #UNITB_INTASK,UNIT_FLAGS(a3)
  552.      bclr #IOB_QUICK,IO_FLAGS(a1)
  553.  
  554.      ENABLE    a0
  555.  
  556.      move.l    a3,a0
  557.      LINKSYS   PutMsg,md_SysLib(a6)
  558.      bra.s     BeginIO_End
  559.  
  560. BeginIO_Immediate:
  561.      ENABLE    a0
  562.  
  563.      bsr  PerformIO
  564.  
  565. BeginIO_End:
  566.      move.l    (sp)+,a3
  567.      rts
  568.  
  569. BeginIO_NoCmd:
  570.      move.b    #IOERR_NOCMD,IO_ERROR(a1)
  571.      bra.s     BeginIO_End
  572.  
  573.  
  574. ;
  575. ; PerformIO actually dispatches an io request.  It expects a3 to already
  576. ; have the unit pointer in it.  a6 has the device pointer (as always).
  577. ; a1 has the io request.  Bounds checking has already been done on
  578. ; the io request.
  579. ;
  580.  
  581. PerformIO:     ; ( iob:a1, unitptr:a3, devptr:a6 )
  582.      move.l    a2,-(sp)
  583.      move.l    a1,a2
  584.  
  585.      move.w    IO_COMMAND(a2),d0
  586.      lea  cmdtable(pc),a0
  587.      move.l    0(a0,d0.w),a0
  588.  
  589.      jsr  (a0)
  590.  
  591.      move.l    (sp)+,a2
  592.      rts
  593.  
  594. ;
  595. ; TermIO sends the IO request back to the user.  It knows not to mark
  596. ; the device as inactive if this was an immediate request or if the
  597. ; request was started from the server task.
  598. ;
  599.  
  600. TermIO:        ; ( iob:a1, unitptr:a3, devptr:a6 )
  601.      move.w    IO_COMMAND(a1),d0
  602.      move.w    #IMMEDIATES,d1
  603.      btst d0,d1
  604.      bne.s     TermIO_Immediate
  605.  
  606.      ;------ we may need to turn the active bit off.
  607.      btst #UNITB_INTASK,UNIT_FLAGS(a3)
  608.      bne.s     TermIO_Immediate
  609.  
  610.      ;------ the task does not have more work to do
  611.      bclr #UNITB_ACTIVE,UNIT_FLAGS(a3)
  612.  
  613. TermIO_Immediate:
  614.      ;------ if the quick bit is still set then we don't need to reply
  615.      ;------ msg -- just return to the user.
  616.      btst #IOB_QUICK,IO_FLAGS(a1)
  617.      bne.s     TermIO_End
  618.  
  619.      LINKSYS   ReplyMsg,md_SysLib(a6)
  620.  
  621. TermIO_End:
  622.      rts
  623.      
  624.  
  625. AbortIO:  ; ( iob: a1, device:a6 )
  626.  
  627. ;----------------------------------------------------------------------
  628. ;
  629. ; here begins the functions that implement the device commands
  630. ; all functions are called with:
  631. ;    a1 -- a pointer to the io request block
  632. ;    a2 -- another pointer to the iob
  633. ;    a3 -- a pointer to the unit
  634. ;    a6 -- a pointer to the device
  635. ;
  636. ; Commands that conflict with 68000 instructions have a "My" prepended
  637. ; to them.
  638. ;----------------------------------------------------------------------
  639.  
  640. Invalid:
  641.      move.b    #IOERR_NOCMD,IO_ERROR(a1)
  642.      bsr  TermIO
  643.      rts
  644.  
  645. MyReset:
  646.  
  647.      ; !!! fill me in !!!
  648.      ; !!! fill me in !!!
  649.      ; !!! fill me in !!!
  650.      ; !!! fill me in !!!
  651.  
  652.  
  653. ;
  654. ; the Read command acts as an infinite source of nulls.  It clears
  655. ; the user's buffer and marks that many bytes as having been read.
  656. ;
  657.  
  658. Read:
  659.      move.l    IO_DATA(a1),a0
  660.      move.l    IO_LENGTH(a1),d0
  661.      move.l    d0,IO_ACTUAL(a1)
  662.  
  663.      ;------ deal with a zero length read
  664.      beq.s     Read_End
  665.  
  666.      ;------ now copy the data
  667.      CLEAR     d1
  668.  
  669. Read_Loop:
  670.      move.b    d1,(a0)+
  671.      subq.l    #1,d0
  672.      bne.s     Read_Loop
  673.  
  674. Read_End:
  675.      bsr  TermIO
  676.      rts
  677.  
  678.  
  679. ;
  680. ; the Write command acts as bit bucket.  It clears acknowledges all
  681. ; the bytes the user has tried to write to it.
  682. ;
  683.  
  684. Write:
  685.      move.l    IO_LENGTH(a1),IO_ACTUAL(a1)
  686.  
  687.      bsr  TermIO
  688.      rts
  689.  
  690. ;
  691. ; Update and Clear are internal buffering commands.  Update forces all
  692. ; io out to its final resting spot, and does not return until this is
  693. ; done.  Clear invalidates all internal buffers.  Since this device
  694. ; has no internal buffers, these commands do not apply.
  695. ;
  696.  
  697. Update:
  698. Clear:
  699.      bra  Invalid
  700.  
  701. ;
  702. ; the Stop command stop all future io requests from being
  703. ; processed until a Start command is received.  The Stop
  704. ; command is NOT stackable: e.g. no matter how many stops
  705. ; have been issued, it only takes one Start to restart
  706. ; processing.
  707. ;
  708.  
  709. MyStop:
  710.      bset #MDUB_STOPPED,UNIT_FLAGS(a3)
  711.  
  712.      bsr  TermIO
  713.      rts
  714.      
  715. Start:
  716.      bsr  InternalStart
  717.  
  718.      move.l    a2,a1
  719.      bsr  TermIO
  720.  
  721.      rts
  722.  
  723. InternalStart:
  724.      ;------ turn processing back on
  725.      bclr #MDUB_STOPPED,UNIT_FLAGS(a3)
  726.  
  727.      ;------ kick the task to start it moving
  728.      move.l    a3,a1
  729.      CLEAR     d0
  730.      move.l    MP_SIGBIT(a3),d1
  731.      bset d1,d0
  732.      LINKSYS   Signal,md_SysLib(a3)
  733.  
  734.      rts
  735.  
  736. ;
  737. ; Flush pulls all io requests off the queue and sends them back.
  738. ; We must be careful not to destroy work in progress, and also
  739. ; that we do not let some io requests slip by.
  740. ;
  741. ; Some funny magic goes on with the STOPPED bit in here.  Stop is
  742. ; defined as not being reentrant.  We therefore save the old state
  743. ; of the bit and then restore it later.  This keeps us from
  744. ; needing to DISABLE in flush.  It also fails miserably if someone
  745. ; does a start in the middle of a flush.
  746. ;
  747.  
  748. Flush:
  749.      movem.l   d2/a6,-(sp)
  750.  
  751.      move.l    md_SysLib(a6),a6
  752.  
  753.      bset #MDUB_STOPPED,UNIT_FLAGS(a3)
  754.      sne  d2
  755.  
  756. Flush_Loop:
  757.      move.l    a3,a0
  758.      CALLSYS   GetMsg
  759.  
  760.      tst.l     d0
  761.      beq.s     Flush_End
  762.  
  763.      move.l    d0,a1
  764.      move.b    #IOERR_ABORTED,IO_ERROR(a1)
  765.      CALLSYS   ReplyMsg
  766.  
  767.      bra.s     Flush_Loop
  768.  
  769. Flush_End:
  770.  
  771.      move.l    d2,d0
  772.      movem.l   (sp)+,d2/a6
  773.  
  774.      tst.b     d0
  775.      beq.s     1$
  776.  
  777.      bsr  InternalStart
  778. 1$:
  779.  
  780.      move.l    a2,a1
  781.      bsr  TermIO
  782.  
  783.      rts
  784.  
  785. ;
  786. ; Foo and Bar are two device specific commands that are provided just
  787. ; to show you how to add your own commands.  The currently return that
  788. ; no work was done.
  789. ;
  790.  
  791. Foo:
  792. Bar:
  793.      CLEAR     d0
  794.      move.l    d0,IO_ACTUAL(a1)
  795.  
  796.      bsr  TermIO
  797.      rts
  798.  
  799. ;----------------------------------------------------------------------
  800. ;
  801. ; here begins the process related routines
  802. ;
  803. ; A Process is provided so that queued requests may be processed at
  804. ; a later time.
  805. ;
  806. ;
  807. ; Register Usage
  808. ; ==============
  809. ; a3 -- unit pointer
  810. ; a6 -- syslib pointer
  811. ; a5 -- device pointer
  812. ; a4 -- task (NOT process) pointer
  813. ; d7 -- wait mask
  814. ;
  815. ;----------------------------------------------------------------------
  816.  
  817. ; some dos magic.  A process is started at the first executable address
  818. ; after a segment list.  We hand craft a segment list here.  See the
  819. ; the DOS technical reference if you really need to know more about this.
  820.  
  821.      cnop 0,4            ; long word allign
  822.      DC.L 16             ; segment length -- any number will do
  823. myproc_seglist:
  824.      DC.L 0              ; pointer to next segment
  825.  
  826. ; the next instruction after the segment list is the first executable address
  827.  
  828. Proc_Begin:
  829.  
  830.      move.l    _AbsExecBase,a6
  831.  
  832.           PUTMSG    1,<'%s/Proc: called'>
  833.           XLIB Debug
  834.           CALLSYS   Debug
  835.  
  836.      ;------ wait for our first packet
  837.      SUB.L     a1,a1               ; <my task> = FindTask(0)
  838.      CALLSYS   FindTask
  839.      move.l    d0,a0
  840.      move.l    d0,a4               ; save task in a4
  841.      lea  pr_MsgPort(a0),a0   ; get msg port for my processes
  842.      CALLSYS   WaitPort
  843.  
  844.      ;------ take msg off the port
  845.      move.l    d0,a1
  846.      move.l    d0,a2               ; save the message
  847.      CALLSYS   Remove
  848.  
  849.      ;------ get our parameters out of it
  850.      move.l    mdm_Device(a2),a5        ; a5 is now our device
  851.      move.l    mdm_Unit(a2),a3
  852.  
  853.           IFGE INFO_LEVEL-1
  854.           pea  0
  855.           move.b    mdu_UnitNum(a3),3(sp)
  856.           move.l    a3,-(sp)
  857.           move.l    a5,-(sp)
  858.           PUTMSG    1,<'%s/Proc: dev 0x%lx unit 0x%lx/%ld'>
  859.           lea  12(sp),sp
  860.           ENDC
  861.  
  862.      ;------ Allocate the right signal
  863.      moveq     #-1,d0              ; -1 is any signal at all
  864.      CALLSYS   AllocSignal
  865.  
  866.      move.b    d0,MP_SIGBIT(a3)
  867.      move.b    #PA_SIGNAL,MP_FLAGS(a3)
  868.  
  869.      ;------ change the bit number into a mask, and save in d7
  870.      CLEAR     d7
  871.      bset d0,d7
  872.  
  873.  
  874.      ;------
  875.      ;------ OK, kids, we are done with initialization.  We now
  876.      ;------ can start the main loop of the driver.  It goes
  877.      ;------ like this.  Because we had the port marked PA_IGNORE
  878.      ;------ for a while (in InitUnit) we jump to the getmsg
  879.      ;------ code on entry.
  880.      ;------
  881.      ;------        wait for a message
  882.      ;------        lock the device
  883.      ;------        get a message.  if no message unlock device and loop
  884.      ;------        dispatch the message
  885.      ;------        loop back to get a message
  886.      ;------
  887.  
  888.      bra.s     Proc_CheckStatus
  889.  
  890.      ;------ main loop: wait for a new message
  891. Proc_MainLoop:
  892.      move.l    d7,d0
  893.      CALLSYS   Wait
  894.  
  895. Proc_CheckStatus:
  896.      ;------ see if we are stopped
  897.      btst #MDUB_STOPPED,UNIT_FLAGS(a3)
  898.      bne.s     Proc_MainLoop       ; device is stopped
  899.  
  900.      ;------ lock the device
  901.      bset #UNITB_ACTIVE,UNIT_FLAGS(a3)
  902.      bne.s     Proc_MainLoop       ; device in use
  903.  
  904.      ;------ get the next request
  905. Proc_NextMessage:
  906.      move.l    a3,a0
  907.      CALLSYS   GetMsg
  908.      tst.l     d0
  909.      beq.s     Proc_Unlock         ; no message?
  910.  
  911.      ;------ do this request
  912.      move.l    d0,a1
  913.      exg  a5,a6               ; put device ptr in right place
  914.      bsr  PerformIO
  915.      exg  a5,a6               ; get syslib back in a6
  916.  
  917.      bra.s     Proc_NextMessage
  918.  
  919.      ;------ no more messages.  back ourselves out.
  920. Proc_Unlock:
  921.      and.b     #$ff&(UNITB_ACTIVE!UNITB_INTASK),UNIT_FLAGS(a3)
  922.      bra  Proc_MainLoop
  923.  
  924.  
  925. Proc_Fail:
  926.      ;------ we come here on initialization failures
  927.      bsr  FreeUnit
  928.      rts
  929.  
  930.  
  931. ;----------------------------------------------------------------------
  932. ; EndCode is a marker that show the end of your code.
  933. ; Make sure it does not span sections nor is before the
  934. ; rom tag in memory!  It is ok to put it right after
  935. ; the rom tag -- that way you are always safe.  I put
  936. ; it here because it happens to be the "right" thing
  937. ; to do, and I know that it is safe in this case.
  938. ;----------------------------------------------------------------------
  939. EndCode:
  940.  
  941.      END
  942.  
  943.